tensor

tensor(M,N) -- tensor product of rings or monoids.

This method allows all of the options available for monoids, see monoid for details. This routine essentially combines the variables of M and N into one monoid.

For rings, the rings should be quotient rings of polynomial rings over the same base ring.

Here is an example with monoids.

     i1 = M = monoid[a..d, MonomialOrder => Eliminate 1]
     
     o1 = [a,b,c,d,MonomialOrder => Eliminate{1}]
     
     o1 : GeneralOrderedMonoid

     i2 = N = monoid[e,f,g, Degrees => {1,2,3}]
     
     o2 = [e,f,g,Degrees => {{1},{2},{3}}]
     
     o2 : GeneralOrderedMonoid

     i3 = P = tensor(M,N,MonomialOrder => GRevLex)
     
     o3 = [a,b,c,d,e,f,g,Degrees => {{1},{1},{1},{1},{1},{2},{3}},MonomialOrder => GRevLex]
     
     o3 : GeneralOrderedMonoid

     i4 = describe P
     
     [a,b,c,d,e,f,g,Degrees=>{{1}, {1}, {1}, {1}, {1}, {2}, {3}},MonomialOrder=>GRevLex]

     i5 = tensor(M,M,Variables => {x_0 .. x_7}, MonomialOrder => ProductOrder{4,4})
     
     o5 = [x ,x ,x ,x ,x ,x ,x ,x ,MonomialOrder => ProductOrder{4,4}]
            0  1  2  3  4  5  6  7
     
     o5 : GeneralOrderedMonoid

     i6 = describe oo
     
     [x_0,x_1,x_2,x_3,x_4,x_5,x_6,x_7,MonomialOrder=>ProductOrder{4, 4}]

Here is a similar example with rings.

     i7 = tensor(ZZ/101[x,y], ZZ/101[r,s], MonomialOrder => Eliminate 2)
     
           ZZ
     o7 = ---[x,y,r,s,MonomialOrder => Eliminate{2}]
          101
     
     o7 : PolynomialRing